Erweiterte Datenträgerbereinigung unter Windows 10

Diskutiere Erweiterte Datenträgerbereinigung unter Windows 10 im Windows 10 FAQ Forum im Bereich Windows 10 Foren; Oftmals stellt man fest, dass Windows auf der Systempartition immer mehr Platz belegt und man deshalb vor der Frage steht, wie man den Platzbedarf...
areiland

areiland

Super-Moderator
Threadstarter
Dabei seit
25.08.2014
Beiträge
29.643
Ort
Ludwigshafen
Version
Windows 10 Pro x64 immer aktuell!
System
970M Pro3, FX8350, RX560, 16GB DDR3 1600, 860Evo256 GB, MK7559GSXP, SH224BB, BenQ GW2780
Oftmals stellt man fest, dass Windows auf der Systempartition immer mehr Platz belegt und man deshalb vor der Frage steht, wie man den Platzbedarf von Windows wieder senken kann. Die Lösung dazu ist, wie so vieles, in Windows direkt eingebaut und lässt sich sehr leicht ausführen.

Hierzu ist zu sagen - dass Windows und die installierten Programme sehr viele temporäre Dateien anlegen. Diese temporären Dateien werden dafür angelegt, um genutzte Inhalte nicht im Arbeitsspeicher halten zu müssen oder um Änderungen an geöffneten Dokumenten nicht sofort speichern zu müssen. Windows speichert so auch Daten, die erst später genutzt werden sollen. Es ist also eine sinnvolle Sache was Windows da tut. Ausserdem werden so auch Dateien hinterlegt, die eventuell später noch mal benötigt werden oder sinnvoll sein könneten. Nicht nur Windows speichert so temporäre Dateien, sondern jedes Programm das unter Windows läuft. Ausserdem lässt sich auch der Ordner Windows.old, der nach grösseren Systemupdates angelegt wird, so auf einfachste Art entfernen.

Um diese Dateien zu bereinigen, reicht es aus im Explorer einen Rechtsklick auf Laufwerk C: auszuführen und "Eigenschaften" zu wählen - hier klickt man nun auf den Button "Bereinigen".

Eigenschaften von C.jpg

Windows führt nun zunächst eine Inventur aus, um die löschbaren Daten zu ermitteln.

Datenträgerbereinigung.jpg

Danach präsentiert die Windows Datenträgerbereinigung eine Liste mit den Kategorien, die bereinigt werden können. Hier findet man dann auch den Button "Systemdateien bereinigen". Diesen klickt man nun ebenfalls an, um die Liste noch etwas zu erweitern. Jetzt führt Windows eine weitere Inventur durch.

Datenträgerbereinigung - Systemdateien bereinigen.jpg

Nachdem diese Inventur durchgelaufen ist, kommt das schon bekannte Fenster mit der Liste der zu bereinigenden Kategorien erneut. Sämtliche Kategorien hakt man an. Hier gibt es aber nun ebenfalls den Tab "Weitere Optionen", auf dem man auch die Wiederherstellungspunkte (bis auf den letzten) und die Schattenkopien bereinigen lassen kann.

Datenträgerbereinigung - Systemdateien bereinigen weitere Optionen.jpg

Datenträgerbereinigung - Systemdateien bereinigen weitere Optionen Wiederherstellungspunkte.jpg

Diesen Button klickt man jetzt an - um auch seine Wiederherstellungpunkte (bis auf den letzten erstellten Punkt) bereinigen zu lassen. Anschliessend zweimal auf "OK" klicken um den ganzen Vorgang ausführen zu lassen. Speziell der Punkt "Updatebereinigung" kann allerdings nicht direkt abgeschlossen werden, denn die meisten Daten werden hier zuerst für die Entfernung vorgemerkt, erst bei einem der folgenden Neustarts des Systems wird dieser Vorgang abgeschlossen werden.

Man kann die Liste der zu bereinigenden Punkte noch einmal etwas erweitern. Dazu muss man nur eine Eingabeaufforderung mit Adminrechten öffnen (WIN+X drücken und "Eingabeaufforderung (Administrator)" wählen) und dort die Befehlszeile: Cleanmgr /sageset:65535 & cleanmgr /sagerun:65535 ausführen. Dies bringt den gleichen Dialog wie oben hervor, der ist allerdings dann um einige wenige Kategorien erweitert. Da dies ohnehin schon mit Adminrechten ausgeführt wird, ist auch sofort der Tab "Weitere Optionen" sichtbar und der Button "Systemdateien bereinigen" fehlt.
 
Zuletzt bearbeitet:
areiland

areiland

Super-Moderator
Threadstarter
Dabei seit
25.08.2014
Beiträge
29.643
Ort
Ludwigshafen
Version
Windows 10 Pro x64 immer aktuell!
System
970M Pro3, FX8350, RX560, 16GB DDR3 1600, 860Evo256 GB, MK7559GSXP, SH224BB, BenQ GW2780
Für Spezialfälle, die wegen Updateproblemen oder nach erfolgreichen Updates/Upgrades erweiterte Optionen haben möchten, hab ich hier noch eine stark erweiterte Variante der Datenträgerbereinigung erstellt. Diese leert z.B. die Temp Ordner, entfernt die heruntergeladenen Updatedateien und löscht die temporären Installationsordner ($Windows.~BT und $Windows.~WS). Danach wird das Löschen der Schattenkopien angestossen, das ohne Nutzereingriff abläuft.

Anschliessend wird dann eine Datenträgerbereinigung mit maximalen Optionen angestossen, von der die oben genannten Befehle: Cleanmgr /sageset:65535 und cleanmgr /sagerun:65535 genutzt werden. Hier müssen bei erstmaliger Ausführung sämtliche zu bereinigenden Kategorien gewählt werden. Nach der Auswahl und der Bestätigung mit "OK" wird die Datenträgerbereinigung dann auf allen angeschlossenen Laufwerken vorgenommen. In dieser Variante gibt die Datenträgerbereinigung keine Auskunft über die löschbaren Datenvolumina!

Diese Variation wird durch das hier angefügte Script durchgeführt:

Anhang anzeigen Datenträgerbereinigung.zip

Das Script herunterladen, entpacken und dann über einen Rechtsklick und der Auswahl "Als Administrator ausführen" mit erhöhten Rechten laufen lassen, damit ein Maximum an Bereinigung durchgeführt werden kann. Das Script schliesst sich nach Beendigung aller vorgesehenen Möglichkeiten von selbst, deshalb ist ab der Datenträgerbereinigung nichts mehr zu tun, als abzuwarten bis das Fenster zugeht. In eurem eigenen Interesse solltet ihr vor der Ausführung des Scripts alle offenen Programme schliessen, damit die Bereinigung möglichst umfassend ablaufen kann.

Da ich das löschen von Unterordnern, z.B. in den temporären Verzeichnissen, normalerweise nur dann durchführen kann - wenn ich den übergeordneten Ordner ebenfalls lösche oder die Ordnernamen kenne - hab ich eine Vorgehensweise genutzt, die es trotzdem erlaubt dass ich untergordnete Verzeichnisse entferne, deren Namen ich nicht kenne. Dafür erstelle ich ein leeres Verzeicnis, dessen nicht vorhandenen Inhalt ich anschliessend mit Robocopy /mir in die zu leerenden Ordner mergen lasse - so wird zwar nichts kopiert, aber vorhandene Ordner und Dateien werden gelöscht. Nachdem das erledigt ist, wird der leere Ordner ebenfalls wieder entfernt.

Robocopy löscht dadurch alle nicht gesperrten Dateien und Ordner in den angegebenen Verzeichnissen, lediglich vom System oder Programmen gesperrte Dateien und Ordner bleiben erhalten. Das Script erstellt ausserdem von allen Vorgängen auf dem Desktop das Log Datenträgerbereinigung.txt, so dass man nachverfolgen kann, was im einzelnen getan wurde. Die Robocopy Abschnitte des Logs geben dabei Auskunft darüber, was entfernt werden konnte und was beibehalten werden musste. Durch die Vorgehensweise mit Robocopy hab ich es mir einfach nur erspart, die entsprechenden Ordner zu löschen und neu anzulegen, was bei gesperrten Dateien in diesen Ordnern nur unnötige Fehlermeldungen provozieren würde.

Nicht vorhandene, aber zu löschende Ordner, provozieren zwar im CMD Fenster den Hinweis "Datei nicht vorhanden", hindern das Script aber nicht an seiner weiteren Ausführung!

Für die Interessierten hab ich den Quelltext des Scriptes hier angehängt:
Code:
@Echo off
chcp 1252 >nul
set log="%userprofile%\Desktop\Datenträgerbereinigung.log"
set l=C:\Leer
md %l%
@Echo #################################################################################################################### >%log%
@Echo Von Benutzer: %Username% wurde auf PC: %Computername% eine erweiterte Datenträgerbereinigung gestartet! >>%log%
@Echo #################################################################################################################### >>%log%
@Echo. >>%log%
@Echo Nachfolgend sind die einzelnen Bearbeitungschritte mit ihren Ergebnissen aufgeführt: >>%log%
@Echo. >>%log%
@Echo #################################################################################################################### >>%log%
@Echo Den Ordner C:\Windows\Temp bereinigen! >>%log%
@Echo #################################################################################################################### >>%log%
robocopy %l% C:\Windows\Temp /mir >>%log%
@Echo. >>%log%
@Echo #################################################################################################################### >>%log%
@Echo Den Ordner %temp% bereinigen! >>%log%
@Echo #################################################################################################################### >>%log%
robocopy %l% %Temp% /mir >>%log%
@Echo. >>%log%
@Echo #################################################################################################################### >>%log%
@Echo Den Downloadordner von Windows Update bereinigen! >>%log%
@Echo #################################################################################################################### >>%log%
robocopy %l% C:\Windows\SoftwareDistribution\Download /mir >>%log%
@Echo. >>%log%
@Echo #################################################################################################################### >>%log%
@Echo Den Ordner mit den Dateien bereinigen, die während des Neustarts installiert werden! >>%log%
@Echo #################################################################################################################### >>%log%
robocopy %l% C:\Windows\SoftwareDistribution\PostRebootEventCache.V2 /mir >>%log%
@Echo. >>%log%
@Echo #################################################################################################################### >>%log%
@Echo Den Ordner C:\Windows\Prefetch bereinigen! >>%log%
@Echo #################################################################################################################### >>%log%
robocopy %l% C:\Windows\Prefetch /mir >>%log%
@Echo. >>%log%
@Echo #################################################################################################################### >>%log%
@Echo Den temporären Patchordner des Installers bereinigen! >>%log%
@Echo #################################################################################################################### >>%log%
robocopy %l% C:\Windows\Installer\$PatchCache$ /mir >>%log%
@Echo. >>%log%
@Echo #################################################################################################################### >>%log%
@Echo Den Ordner C:\$Windows.~BT löschen! >>%log%
@Echo #################################################################################################################### >>%log%
@Echo. >>%log%
rd /s /q C:\$Windows.~BT >>%log%
@Echo #################################################################################################################### >>%log%
@Echo Den Ordner C:\$Windows.~WS löschen! >>%log%
@Echo #################################################################################################################### >>%log%
@Echo. >>%log%
rd /s /q C:\$Windows.~WS >>%log%
@Echo #################################################################################################################### >>%log%
@Echo Die Schattenkopien bereinigen! >>%log%
@Echo #################################################################################################################### >>%log%
@Echo. >>%log%
vssadmin delete shadows /all /quiet >>%log%
@Echo. >>%log%
rd /s /q %l% >>%log%
@Echo. >>%log%
@Echo #################################################################################################################### >>%log%
@Echo Die eigentliche Datenträgerbereinigung wird durchgeführt! >>%log%
@Echo #################################################################################################################### >>%log%
@Echo. >>%log%
cleanmgr /sageset:65536
cleanmgr /sagerun:65536
@Echo #################################################################################################################### >>%log%
@Echo Die Datenträgerbereinigung ist nun abgeschlossen, der temporäre Ordner %l% wird gelöscht und das Script beendet! >>%log%
@Echo #################################################################################################################### >>%log%

Das Script ist auch unter Windows 7 und 8/8.1 ausführbar, ohne dass es zu Komplikationen käme!

Datenträgerbereinigung - Windows 7.jpg
 
Zuletzt bearbeitet:
areiland

areiland

Super-Moderator
Threadstarter
Dabei seit
25.08.2014
Beiträge
29.643
Ort
Ludwigshafen
Version
Windows 10 Pro x64 immer aktuell!
System
970M Pro3, FX8350, RX560, 16GB DDR3 1600, 860Evo256 GB, MK7559GSXP, SH224BB, BenQ GW2780
Ein Hinweis: Das Script wurde durch eine aktualisierte Version ersetzt, in der jetzt auch die Bereinigung des Ordners: C:\Windows\SoftwareDistribution\PostRebootEventCache.V2 enthalten ist. Der dokumentierte Code des Scriptes ist ebenfalls entsprechend ergänzt worden.
 
Papa77

Papa77

Erfahrener Benutzer
Dabei seit
17.08.2015
Beiträge
271
Version
Windows 10 Pro 64bit
System
AMD Ryzen5 2600, GIGABYTE B450 AORUS M, 16 GB DDR4 RAM,SAPPHIRE PULSE RX 570 8Gb,Samsung PM981 512GB
Danke Alex
 
Netlogger

Netlogger

Erfahrener Benutzer
Dabei seit
14.03.2015
Beiträge
561
Ort
Nürnberg
Version
Windows 10 Home 64bit 20H1 (Build : 19043,1151
System
AMD A4-3420 APU 8GB RAM , R7 270 Serie
Wie immer sehr gute Arbeit Alex -->> Danke :D
 
G

Gast4308

Ich habe das Script gerade mal heruntergeladen und wie beschrieben ausgeführt. Es wird mir aber keine Datenträgerbereinigung.txt auf dem Desktop angelegt. Was ist da los?
 
areiland

areiland

Super-Moderator
Threadstarter
Dabei seit
25.08.2014
Beiträge
29.643
Ort
Ludwigshafen
Version
Windows 10 Pro x64 immer aktuell!
System
970M Pro3, FX8350, RX560, 16GB DDR3 1600, 860Evo256 GB, MK7559GSXP, SH224BB, BenQ GW2780
Leerzeichen im Benutzernamen? Irgendwie hab ich das nämlich noch nicht behoben.
 
ungarnjoker

ungarnjoker

Erfahrener Benutzer
Dabei seit
25.01.2015
Beiträge
3.315
Ort
In Ungarn am Balaton, vorher im schönen Hamburg
Version
21H2 (Build 19044.1348)
System
MSI GL72 6QFi781FD 16GB RAM 1TB SSD+250GB SATA + ca. 20TB extern üb. div. USB-2,3&C, nVIDIA GTX960M
Versuche mal, die Zeile 3 dahingehend zu ändern:
set log="%userprofile%\Desktop\Datenträgerbereinigung.log"

Alex, die Zeile 2 (chcp 1252 >nul) produziert aber unschöne Zeichen im Log.
 
areiland

areiland

Super-Moderator
Threadstarter
Dabei seit
25.08.2014
Beiträge
29.643
Ort
Ludwigshafen
Version
Windows 10 Pro x64 immer aktuell!
System
970M Pro3, FX8350, RX560, 16GB DDR3 1600, 860Evo256 GB, MK7559GSXP, SH224BB, BenQ GW2780
Inwiefern produziert der Codepagewechsel unschöne Zeichen? Der steht drin damit die Umlaute korrekt dargestellt werden.
 
Zuletzt bearbeitet:
ungarnjoker

ungarnjoker

Erfahrener Benutzer
Dabei seit
25.01.2015
Beiträge
3.315
Ort
In Ungarn am Balaton, vorher im schönen Hamburg
Version
21H2 (Build 19044.1348)
System
MSI GL72 6QFi781FD 16GB RAM 1TB SSD+250GB SATA + ca. 20TB extern üb. div. USB-2,3&C, nVIDIA GTX960M
areiland

areiland

Super-Moderator
Threadstarter
Dabei seit
25.08.2014
Beiträge
29.643
Ort
Ludwigshafen
Version
Windows 10 Pro x64 immer aktuell!
System
970M Pro3, FX8350, RX560, 16GB DDR3 1600, 860Evo256 GB, MK7559GSXP, SH224BB, BenQ GW2780
Öffne die Datei mal mit Notepad! Dann siehst Du dass die Umlaute korrekt dargestellt werden. Voreingestellt ist für die Konsole nämlich die Codepage 850, was der Dos Zeichensatz (ASCII) ist, während die Codepage 1252 den ANSI Zeichensatz verwendet. Wenn Dein Editor mit der Codepage 850 besser klarkommt, dann lösch die Zeile oder kommentiere sie einfach durch ein vorangestelltes Rem oder einen doppelten Doppelpunkt aus.

Das Script wurde ausgetauscht und berücksichtigt jetzt die Leerzeichen im Benutzernamen.
 
ungarnjoker

ungarnjoker

Erfahrener Benutzer
Dabei seit
25.01.2015
Beiträge
3.315
Ort
In Ungarn am Balaton, vorher im schönen Hamburg
Version
21H2 (Build 19044.1348)
System
MSI GL72 6QFi781FD 16GB RAM 1TB SSD+250GB SATA + ca. 20TB extern üb. div. USB-2,3&C, nVIDIA GTX960M
Öffne die Datei mal mit Notepad! Dann siehst Du dass die Umlaute korrekt dargestellt werden. Voreingestellt ist für die Konsole nämlich die Codepage 850, was der Dos Zeichensatz (ASCII) ist, während die Codepage 1252 den ANSI Zeichensatz verwendet. Wenn Dein Editor mit der Codepage 850 besser klarkommt, dann lösch die Zeile oder kommentiere sie einfach durch ein vorangestelltes Rem oder einen doppelten Doppelpunkt aus.[...]
Die Ursache liegt vermutlich woanders. Jetzt läft es nämlich korrekt. Im ersten Fall hatte ich einfach Dein Listing kopiert, als *.bat abgespeichert und ausgeführt. Jetzt habe ich die ZIP-Datei entpackt und ausgeführt und da werden die Umlaute richtig dargestellt. :nomatter
 
G

Gast

OK, der erste Tipp hat bei mir seltsamerweise etwas Speicherplatz VERbraucht (10mb) :D
Das Skript allerdings ist der Hammer! Das hat mir mal wieder ein paar GB gebracht ohne dass ich viel machen musste.

!!!Vielen Dank!!! Genau soetwas habe ich gesucht. Meine Nerven werden Lieder über ihre Heldentaten schreiben :D
 
R

rainer61

Erfahrener Benutzer
Dabei seit
28.07.2018
Beiträge
146
Version
20H2
System
Intel Celeron CPU 1037U 1,8 GHz, RAM 4GB, Grafikkarte: Intel HD Graphics
Noch ne Putze?
Screenshot (202).png
 
areiland

areiland

Super-Moderator
Threadstarter
Dabei seit
25.08.2014
Beiträge
29.643
Ort
Ludwigshafen
Version
Windows 10 Pro x64 immer aktuell!
System
970M Pro3, FX8350, RX560, 16GB DDR3 1600, 860Evo256 GB, MK7559GSXP, SH224BB, BenQ GW2780
Die neue Datenträgerbereinigung findest Du in den Einstellungen unter "System" als Unterpunkt "Speicher"! Und der Punkt "Optimieren" ist schon immer (mindestens seit Windows XP) der Punkt zur Defragmentierung der Datenträger. Er wurde lediglich in optimieren umbenannt, weil es inzwischen auch noch SSDs gibt, die man optimiert aber nicht defragmentiert. Mein FAQ Artikel stützt sich noch auf die alte Datenträgerbereinigung - was angesichts des Datums, als ich ihn 2015 verfasst hatte, auch nicht weiter verwunderlich ist. Denn die heutigen Möglichkeiten in den Einstellungen gabs damals nämlich noch gar nicht in diesem Umfang und der Cleanmanager war damals noch der Standardbereiniger.
 
Big Eddie Calzone

Big Eddie Calzone

Erfahrener Benutzer
Dabei seit
14.02.2019
Beiträge
286
Version
Win 10 Pro x64 - 20H2 Build: 19042.1348
Ich habe das Script eben gerade in einer VM mit Windows 7 ausgeführt.

Die hatte ich auf Empfehlung von VirtualBox mit 32 GB ausgestattet, von denen nach unzähligen Updates nur noch knapp 1 GB frei war. Nach dem ersten Neustart sind immerhin schon 8,6 GB frei - :) - mal schau'n wie sich das weiter entwickelt ...

Der Scanvorgang hat ziemlich lange gedauert, geschätzt 5 bis 10 Minuten. Ich habe der VM 4 Prozessorkerne spendiert, der Ressourcenmonitor im Screenshot ist derjenige des Wirtssystems.

27664

Oh jeh, jetzt kommen Nachzügler- und Defenderupdates rein.
Ein Neustart später: noch 8,1 GB frei.
 
areiland

areiland

Super-Moderator
Threadstarter
Dabei seit
25.08.2014
Beiträge
29.643
Ort
Ludwigshafen
Version
Windows 10 Pro x64 immer aktuell!
System
970M Pro3, FX8350, RX560, 16GB DDR3 1600, 860Evo256 GB, MK7559GSXP, SH224BB, BenQ GW2780
@Big Eddie Calzone
Wenn Du das unter Windows 7 ausführst - dann beachte bitte, dass die Updatebereinigung erst durch einen Neustart abgeschlossen wird. Denn ein grosser Teil der zu bereinigenden Updates wird dort nur vorgemerkt und dann als Wartungsaufgabe vor dem Login gelöscht. Ein Neustart könnte also nochmal zusätzlichen Platz freigeben.
 
brume

brume

Erfahrener Benutzer
Dabei seit
22.06.2016
Beiträge
1.065
Ort
Zürich
Version
siehe Signatur
System
siehe Signatur
Danke für deine Batchdatei Alex.
Sie ist bei mir ohne Probleme durchgelaufen. Die putzt ja Sachen weg, von deren Existenz ich bisher nicht mal eine Ahnung hatte.
Künftig werde ich für Datenbereinigungen nur noch dieses Tool benützen.
 
Thema:

Erweiterte Datenträgerbereinigung unter Windows 10

Erweiterte Datenträgerbereinigung unter Windows 10 - Ähnliche Themen

Windows 10 Ordner WinSXS oder Dateien aus WinSXS Ordner löschen - Kann man WinSXS löschen?: Es gibt ein Thema das immer wieder einmal auftaucht, wenn es um Speicherplatz geht, und das ist der WinSXS Ordner, den man aber nur sieht, wenn...
Kontakte in Windows 10 einrichten - So leicht kann man Windows 10 Kontakte aktivieren und nutzen: Windows 10 bietet mit der Option für Kontakte eine Möglichkeit, wichtige oder auch öfter benötigte aber nicht ganz so wichtige Kontakte schnell...
Darum solltet ihr anstatt des Administrator-Accounts das Standard Windows-Konto nutzen: Ein Windows-Konto ist für die meisten Computernutzer mittlerweile essenziell. Viele denken, dass es besser ist, sich als Administrator anzumelden...
KB5004745 Cumulatives Update für Win11: Hallo Windows-Insider, Wir sind so aufgeregt, dass so viele von euch die erste Vorschau von Windows 11 ausführen, und wir sind damit beschäftigt...
Windows 10 Kurztipp: Standard-Apps auswählen - Standard-Apps in Windows 10 ändern: Eine weitere kleine Frage die immer wieder auftaucht ist die, wie man seine Standard-Anwendungen in Windows 10 anpassen kann. Nicht jeder will die...

Sucheingaben

erweiterte datenträgerbereinigung win 10

,

erweiterte datenträgerbereinigung

,

datenträgerbereinigung windows 10

,
erweiterte datenträgerbereinigung windows 10
, windows 10 erweiterte datenträgerbereinigung, win 10 erweiterte datenträgerbereinigung, erweiterte systembereinigung win 10, datenträgerbereinigung starten, windows 10 bereinigen cleanmgr, windows 10 erweiterte systembereinigung, chcp ansi, speicherreinigung, windows 10 systemdateien bereinigen fehlt, cmd erweiterte datenträgerbereinigung, bilder eigenschaften von laufwerken windows 10 , https://www.win-10-forum.de/threads/erweiterte-datentraegerbereinigung-unter-windows-10.562/, speicherbereinigung windows 10, speicheroptimierung windows 10, erweiterte datenträger bereinigung, speicheroptimierung einschalten, windows 10 datenträger bereinigen updates, systemdateien bereinigen fehlt, trackstor convertoble windows 10, win 10 datenträgerbereinigung, datenträgerbereinigung windows 10 funktioniert nicht
Oben